实现ASP程序执行时间统计类的代码

Class ClsProcessTimeRecorder 
'程序作者:明月星光 
'作者主页:http://.5iya./blog 
'http://.kuozhanming. 
'ASP程序代码执行时间统计类 

  Private Inti,IntNonceTime,IntDecimal 
  Private IntStartTime,IntEndTime,IntNow,IntNonce 
  Private StrInterval,StrEvent,StrTime,StrStatisticLog,StrFormatInterval 
  Private ArrEvent,ArrTime 

  Private Sub Class_Initialize 
    StrInterval = "|"  '默认分隔符 
    IntDecimal = 4    '小数点后位数 
    StrEvent = "" 
    StrTime = "" 
    StrFormatInterval = "<br />" & vbCrLf 
    IntStartTime = Timer 
    IntNow = IntStartTime 
    IntNonce = IntStartTime 
  End Sub 

  Public Sub Record(StrEventName) 
    StrEvent = StrEvent & StrInterval & Replace(StrEventName,StrInterval,"") 
    StrTime = StrTime & StrInterval & FormatNumber(Timer-IntNow,IntDecimal,True,False,True) 
    IntNow = Timer 
  End Sub 

  Public Property Let Format(StrFormatType) 
    If LCase(Trim(StrFormatType)) = "html" Then 
      StrFormatInterval = "<br />" & vbCrLf 
    Else 
      StrFormatInterval = vbCrLf 
    End If 
  End Property 

  Public Function Statistic 
    If InStr(StrEvent,StrInterval) > 0 Then 
      IntEndTime = Timer 
      ArrEvent = Split(StrEvent,StrInterval) 
      ArrTime = Split(StrTime,StrInterval) 
      StrStatisticLog = StrStatisticLog & "Process Time Record" & StrFormatInterval 
      StrStatisticLog = StrStatisticLog & "--------------------------------------" & StrFormatInterval 
      For Inti = 1 To UBound(ArrEvent) 
        StrStatisticLog = StrStatisticLog & ArrEvent(Inti) & " : " & ArrTime(Inti) & " s" & StrFormatInterval 
      Next 
      StrStatisticLog = StrStatisticLog & "--------------------------------------" & StrFormatInterval 
      StrStatisticLog = StrStatisticLog & "Total : " & FormatNumber(IntEndTime-IntStartTime,IntDecimal,True,False,True) & " s" 
      Statistic = StrStatisticLog 
    Else 
      Statistic = "No Record" 
    End If 
  End Function 

  Public Function Nonce 
    IntNonceTime = FormatNumber(Timer-IntNonce,IntDecimal,True,False,True) 
    IntNonce = Timer 
    Nonce = IntNonceTime 
  End Function 

  Public Function Total 
    Total = FormatNumber(Timer-IntStartTime,IntDecimal,True,False,True) 
  End Function 

End Class 

Dim objRecord,i,k,j,x 

Set objRecord = New ClsProcessTimeRecorder 
objRecord.Format = "html" 

For i = 1 To 100000 
  x = 2 + 2 
Next 

Call objRecord.Record("加法") 
For j = 1 To 100000 
  x = 2  2 
Next 

Call objRecord.Record("乘法") 

For k = 1 To 100000 
  x = 2 ^ 2 
Next 

Call objRecord.Record("开方") 

Response.Write objRecord.Statistic